<?xml version="1.0" encoding="utf-8"?>

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
	<xsl:include href="text-tos.xsl"/>
	<!--Шаблон для корневого элемента-->
	<xsl:template match="/">
		<html>
			<head>
				<meta http-equiv="Content-Type" content="text/html; charset=utf-8" />
			</head>
			<body class="rp_base">
				<xsl:apply-templates/>
			</body>
		</html>
	</xsl:template>
	<!-- шаблон для вопроса-->
	<xsl:template match="question-out">
		<xsl:apply-templates select="custom-out | free-out"/>
	</xsl:template>
	<!--Шаблоны для полей ввода в режиме отчета-->
	<xsl:template match="answ-output[@type='single' or @type='check']">
		<table width="44" border="0">
			<tr valign="top">
				<td >
					<font name="courier new" size="2">
						<xsl:choose>
							<xsl:when test="@number&lt;=26">
								<xsl:value-of select="substring('abcdefghijklmnopqrstuvwxyz',@number,1)"/>
							</xsl:when>
							<xsl:otherwise>
								<xsl:choose>
									<xsl:when test="(@number mod 26)=0">
										<xsl:value-of select="substring('abcdefghijklmnopqrstuvwxyz',floor(@number div 26)-1,1)"/>
										<xsl:value-of select="substring('abcdefghijklmnopqrstuvwxyz',26,1)"/>
									</xsl:when>
									<xsl:otherwise>
										<xsl:value-of select="substring('abcdefghijklmnopqrstuvwxyz',floor(@number div 26),1)"/>
										<xsl:value-of select="substring('abcdefghijklmnopqrstuvwxyz',@number mod 26,1)"/>
									</xsl:otherwise>
								</xsl:choose>
							</xsl:otherwise>
						</xsl:choose>
						<xsl:text>)</xsl:text>
					</font>
				</td>
				<td width="12" valign="top">
					<xsl:choose>
						<xsl:when test="normalize-space(.)=1">
							<img src="resources/select.gif"/>
						</xsl:when>
						<xsl:otherwise>
							<img src="resources/index.gif"/>
						</xsl:otherwise>
					</xsl:choose>
				</td>
			</tr>
		</table>
	</xsl:template>
	<xsl:template match="answ-output[@type='text' or @type='number' or @type='box']">
		<img src="resources/enterL.gif" align="absmiddle"/>
		<span class="rp_base">
			<xsl:value-of select="."/>
		</span>
		<img src="resources/enterP.gif" align="absmiddle"/>
	</xsl:template>
	<!--Различные варианты отображения списка ответов-->
	<xsl:template match="answ-box[@layout='horizontal']">
		<table class="rp_base" border="0">
			<xsl:for-each select="item">
				<tr valign="top">
					<xsl:for-each select="*">
						<td>
							<xsl:apply-templates select="."/>
						</td>
					</xsl:for-each>
				</tr>
			</xsl:for-each>
		</table>
	</xsl:template>
	<xsl:template match="answ-box[@layout='vertical']">
		<table class="rp_base" border="0">
			<tr>
				<xsl:for-each select="item">
					<td>
						<xsl:apply-templates select="*[1]"/>
					</td>
				</xsl:for-each>
			</tr>
			<tr>
				<xsl:for-each select="item">
					<td>
						<xsl:apply-templates select="*[2]"/>
					</td>
				</xsl:for-each>
			</tr>
		</table>
	</xsl:template>
	<!--Шаблон для стандартного вывода вопроса-->
	<xsl:template match="custom-out">
		<table border="0" width="100%" class="rp_base">
			<tr>
				<td>
					<xsl:apply-templates select="q-text"/>
				</td>
			</tr>
		</table>
		<xsl:apply-templates select="answ-box"/>
	</xsl:template>
	<!--Шаблон для свободного вывода вопроса-->
	<xsl:template match="free-out">
		<xsl:apply-templates/>
	</xsl:template>
	<!--Таблица стилей для встроенного языка разметки текста.
	Поскольку все теги встроенного языка разметки совпадают по синтаксису
	и назначению, то данной схеме они просто копируются в выходной поток без
	изменения-->
	<xsl:template match="@*">
		<xsl:copy/>
	</xsl:template>
	<xsl:template match="br|img|i|b|u|sub|sup|font|p|table|tr|td">
		<xsl:copy>
			<xsl:apply-templates select="@*"/>
			<xsl:apply-templates/>
		</xsl:copy>
	</xsl:template>

	
	
</xsl:stylesheet>
